Sistema de Clientes (AIR y SQLite) Parte I (Crear Base de datos)

Esta es la primera parte del proyecto “Sistema de Clientes” desarrollado en AIR con SQLite como administrador de base de datos. Para este proyecto usaremos Flex Builder 3, del cual puedes bajarte una versión de prueba del Flex Builder 3 aquí. Si requieres más información sobre qué es AIR y qué puedes hacer con él visita esta entrada. Los archivos de este proyecto los encontrarás al terminar de publicar todas las partes (entradas) de este proyecto.

Para este proyecto, abre Flex Builder 3 y crea un nuevo proyecto de AIR (File -> New -> Flex Project. Como nombre de proyecto (Project name) ponle Sistema_Clientes; en la sección de Application type selecciona la opción Desktop application (runs in Adobe AIR) y haz click en el botón Finish.
Como lo comenté en la sección de Proyectos, aquí mostraré solamente la información más importante y sobre la cual trata el tema, sin embargo el archivo fuente del proyecto está completo y tiene integrado todo lo que se mostrará en esta entrada y en las siguientes, para así formar un proyecto completo. Dicho lo anterior, a continuación iniciaré la explicación sobre cómo crear una base de datos en SQLite.

Parte 1: Crear Base de Datos en SQLite con AIR

Para mantener organizado el código de nuestro proyecto y para evitar que se pierdan con toda la información aquí mostrada, vamos a dividir el código del proyecto en archivos .as. Estos archivos estarán almacenados en la carpeta actionscript. La estructura de nuestro proyecto será la siguiente:

Imagen 1

Comenzamos con el archivo CrearBaseDatos.as:

Necesitamos de las siguientes librerías para poder tener acceso a los métodos de conexión con la base de datos, la ejecución de los queries, etc. Las clases que usaremos son SQLConnection, SQLErrorEvent y SQL Event:

import flash.data.SQLConnection;
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;
import mx.controls.Alert; /* Haremos uso de los mensajes de alerta, por lo que de una vez añadimos la clase */

Ahora vamos a crear los objetos de estas clases y las variables que requeriremos a lo largo de este archivo:

private var conexion:SQLConnection; // Nuestro objeto de la clase SQLConnection
private var database:File; /* Aquí guardaremos la referencia de nuestro archivo .sqlite que es nuestra base de datos */
private var existeBD:Boolean = false; /* Variable booleana en la cual guardaremos el valor de true si existe la base de datos y false en caso contrario */
private var queryStatement:SQLStatement = new SQLStatement(); /* Creamos una variable de tipo SQLStatement en la cual estableceremos los queries y parámetros de nuestras consultas */

Para crear las sentencias de SQL, necesitamos de un objeto de la clase SQLStatement, a este objeto lo llamamos queryStatement.

La función abreConexion (que mostraremos a continuación) será llamada desde la aplicación principal, es decir desde el archivo Sistema_Clientes.mxml (recuerda que al crear un nuevo proyecto, Flex Builder construye automáticamente un archivo MXML con el nombre del proyecto y el cual es el punto de partida de nuestra aplicación). Esta función se encargará de verificar si existe la base de datos la cual la pasamos como parámetro del constructor de la clase File. Si no existiera la base de datos la aplicación se encargará de crearla. En caso contrario, se establecería la conexión con la base de datos. El nombre de nuestra base de datos será clientesDB.sqlite, presta atención a la primera línea de nuestra función:

private function abreConexion():void {
	/* Asignamos a nuestra variable database el archivo de nuestra base de datos */
	database = new File(File.applicationStorageDirectory.nativePath + "\database\clientesDB.sqlite");
	/* Inicializamos nuestra variable conexion */
	conexion = new SQLConnection();
	/* Creamos el listener que será llamado cuando se abra la conexión a la base de datos */
	conexion.addEventListener(SQLEvent.OPEN, dbAbrirConexion);
	/* Creamos el listener que será llamado cuando exista algún error en la conexión a la bd */
conexion.addEventListener(SQLErrorEvent.ERROR, dbErrorConexion);
queryStatement.sqlConnection = conexion; /* Le asignamos a su propiedad sqlConnection la variable conexion que creamos al inicio del archivo  */ 

	if(!database.exists) { // Comprobamos si existe o no la base de datos
		existeBD = false; // No existe la bd, por lo tanto le asignamos a existeBD el valor de falso
	    	conexion.open(database); // Abrimos la conexión a la bd
	}
	else {
	    	conexion.open(database); // Abrimos la conexión a la bd
	}
}

Observa que al constructor de la clase File le estamos pasando como parámetro el URL de donde estará almacenada nuestra base de datos. Para construir este URL estamos usando la propiedad applicationStorageDirectory, la cual hace referencia al directorio privado donde se encuentra la aplicación. Además, estamos usando la propiedad nativePath la cual nos regresa la ruta completa de acuerdo al sistema operativo donde se encuentra el sistema. A grandes rasgos, esta línea crea un directorio con el nombre de la aplicación (en este caso el directorio se llama Sistema_Clientes) dentro de la carpeta de Application Data (Datos de programa). Esta carpeta es donde los programas que tenemos instalados guardan información o las preferencias del usuario de la computadora. En Windows Vista, el directorio donde está almacenada la base de datos es C:\Users\Nombre_Usuario\AppData\Roaming\Sistema_Clientes. En Windows XP, el directorio es: C:\Documents and Settings\Nombre_Usuario\Datos de programa\Sistema_Clientes.

Al hacer la llamada a la función open, la función dbAbrirConexion será llamada en caso de que no exista error; en caso contrario la función dbErrorConexion será llamada. El código de estas funciones se muestra a continuación:

private function dbAbrirConexion(event:SQLEvent):void {
	if(!existeBD) { /* Si no existe la base de datos, llamamos a la función createTBLCliente */
		createTBLCliente();
	}
}

private function dbErrorConexion():void {
	Alert.show("No se pudo conectar a la base de datos"); /* Mostramos un mensaje de error*/
}

Nuestra base de datos estará conformada por solamente una tabla (sólo para fines del ejercicio, ya que no es común que una base de datos esté formada por sólo una tabla). Nuestra tabla se llama cliente y sus elementos son los siguientes:

Imagen 2

De la imagen anterior podemos determinar que el query para crear esta tabla es:

CREATE TABLE `cliente` (`id` INTEGER PRIMARY KEY  NOT NULL, `nombre` TEXT, `direccion` TEXT, `telefono` TEXT, `email` TEXT)

Este query lo usaremos en la función createTBLCliente, el cual es llamado desde dbAbrirConexion.

private function createTBLCliente():void {
	queryStatement.clearParameters();
	var sql:String = "CREATE TABLE `cliente` ";
	sql += "(`id` INTEGER PRIMARY KEY  NOT NULL, `nombre` TEXT, `direccion` TEXT ";
	sql += ", `telefono` TEXT, `email` TEXT)";
	queryStatement.text = sql;
	try {
		queryStatement.execute();
		insertDefaultData();
	}
	catch(error:SQLError) {
		Alert.show("Error al insertar el registro: " + error.toString());
	}
}

Para crear las sentencias de SQL, necesitamos de un objeto de la clase SQLStatement, a este objeto lo llamamos queryStatement y lo declaramos al inicio del programa. Para asegurarnos de que no tengamos parámetros asignados a este SQLStatement, usamos la función clearParameters, de no hacer esto el programa generará un error indicándonos que la cantidad de parámetros establecidos en el query no concuerda con los parámetros del SQLStatement. Posteriormente declaramos una variable sql de tipo String que contiene el query de crear la tabla de cliente.
La propiedad text de la clase SQLStatement nos permite asignarle la sentencia SQL, por lo que le asignamos la variable sql.

Para poder “cachar” cualquier error que ocurra al ejecutar la sentencia, colocamos la llamada a la función execute dentro del bloque try. Cualquier error que ocurra será detectado y administrador en el bloque catch. En caso de que no exista ningún error al llamar a la función execute, llamaremos a la función insertDefaultData para insertar algunos registros por default.

A continuación pego el código de la función insertDefaultData:

private function insertDefaultData():void {
	queryStatement.clearParameters();
	var sql:String = "INSERT INTO `cliente` (nombre, direccion, telefono, email) VALUES (:nombre, :direccion, :telefono, :email)";
	queryStatement.parameters[":nombre"] = 'Ernesto Trujillo';
	queryStatement.parameters[":direccion"] = 'Avenida Importante #33';
	queryStatement.parameters[":telefono"] = '55667788';
	queryStatement.parameters[":email"] = 'etrujillo@email.com';
	queryStatement.text = sql;
	try {
		queryStatement.execute();
	}
	catch(error:SQLError) {
		Alert.show("Error al crear la tabla cliente: " + error.toString());
	}
}

Este código es similar al de la función createTBLCliente en cuanto a la creación de la variable del SQLStatement, la creación del query y su asignación a la propiedad text. Sin embargo, presta atención en la forma en cómo se le pasan los valores al query; esto es usando dos puntos seguidos de un nombre cualquiera que quieras asignarle. Posteriormente debes establecer el valor de estos parámetros usando la propiedad parameters la cual recibe un arreglo asociativo con los valores del parámetro especificado.

Como recomendación y para que te asegures de que tu base de datos, la tabla y el registro fueron creados, puedes bajar el complemento para Firefox llamado SQLite Manager, el cual es un pequeño y simple administrador de bases SQLite.